Создаем ярлык через командную строку

Создаем ярлык через командную строку

Вступление

При создании bat файлов для автоматизации различных действий, мне не раз приходила мысль о необходимости создания ярлыков через командную строку. К сожалению, обычными средствами командной строки это не сделать. В результате, пришлось искать обходные пути, которым оказался специально созданный VBScript файл, с помощью которого можно из командной строки создавать ярлыки.

Используем VBScript для создания ярлыков

Для создания ярлыка был создан следующий VBScript:

Set objShell = CreateObject("WScript.Shell")

' Проверяем, что получили какие-то параметры
If WScript.Arguments.Count > 0 Then
	Set colArgs = WScript.Arguments.Named
	' Описание ярлыка
	strDescription = colArgs.Item("description")
	' Путь для сохранения создаваемого ярлыка
	strDestination = colArgs.Item("destination")
	' Пользовательский значок создаваемого ярлыка
	strIcon = colArgs.Item("icon")
	' Имя создаваемого ярлыка
	strName = colArgs.Item("name")
	' Путь к объекту, на который ссылается ярлык
	strSource = colArgs.Item("source")

	Set objLink = objShell.CreateShortcut(strDestination & "\" & strName & ".lnk")
	' Устанавливаем описание ярлыка, только если задан аргумент description
	If 0 < Len(strDescription) Then
		objLink.Description = strDescription
	End If
	' Устанавливаем пользовательский значок, только если задан аргумент icon
	If 0 < Len(strIcon) Then
		objLink.IconLocation = strIcon
	End If
	objLink.TargetPath = strSource
	objLink.Save
End If

Поддерживаемые параметры:

  • /source:[ПУТЬ] - обязательный параметр, полный путь к директории или файлу, на который будет ссылаться ярлык.
    Пример: /source:"C:\Windows\System32\Notepad.exe"
  • /destination:[ПУТЬ] - обязательный параметр, путь к директории, в которой следует создать ярлык.
    Пример: /destination:"%USERPROFILE%\Desktop"
  • /name:[ИМЯ] - обязательный параметр, имя создаваемого ярлыка.
    Пример: /name:"Блокнот"
  • /description:[ОПИСАНИЕ] - необязательный параметр, описание создаваемого ярлыка, которое будет появляться при наведении на него курсором мыши.
    Пример: /description:"Запуск Блокнота"
  • /icon:[ПУТЬ К ФАЙЛУ,ИНДЕКС ЗНАЧКА] - необязательный параметр, пользовательский значок. Следует указать путь к файлу со значками (например, C:\Windows\System32\mmcndmgr.dll), и индекс значка в этом файле (например, 40).
    Пример: /icon:"C:\Windows\System32\mmcndmgr.dll, 40"

Примеры использования:

Создаем ярлык для Блокнота:

CreateShortcut.vbs /source:"C:\Windows\System32\Notepad.exe" /destination:"%USERPROFILE%\Desktop" /name:"Блокнот"

Обычный ярлык.

Создаем ярлык для Блокнота, добавляем ему описание и модный значок:

CreateShortcut.vbs /source:"C:\Windows\System32\Notepad.exe" /destination:"%USERPROFILE%\Desktop" /name:"Блокнот" /description:"Запуск Блокнота" /icon:"C:\Windows\System32\mmcndmgr.dll, 40"

Ярлык с другим значком.

Была ли эта статья Вам полезна?

Добавить комментарий

Ваш адрес email не будет опубликован.

Напоминаем Вам, что Ваше сообщение будет опубликовано только после проверки администратором сайта. Обычно это занимает 1-2 рабочих дня.